Работа в 1С 39

<Фильтр> – идентификатор переменной, в которую данный метод вернет строковое значение – фильтр индекса.

НомерПоля(<НазваниеПоля>) предназначен для определения номера поля по его названию.

Параметры:

<HaзвaниeПoля> – строковое выражение с названием поля.

Возвращаемое значение: числовое значение номера поля.

Пример:

НомП = ДБФ.НомерПоля("CODE");

ДобавитьПоле(<Название>, <Тип>, <Длина>, <Точность>) – добавляет поле в описание структуры базы. Данный метод можно использовать только перед созданием новой базы.

Параметры:

<Название> – имя создаваемого поля.

<Тип> – строковое или числовое выражение – тип создаваемого поля. Допустимые значения:

1 или"N" – число;

2 или "S" – строка;

3 или "D" – дата;

4 или "L" – логическое;

5 или "F" – то же, что и 1, т. е. число;

6 или "М" – memo (не поддерживается).

<Длина> – общая длина создаваемого поля.

<Точность> – длина создаваемого поля после десятичной точки (только для числовых полей).

Пример:

ДБФ = СоздатьОбъект("XBase");

ДБФ.ДобавитьПоле("CODE", 1, 19, 3);

ДБФ.ДобавитьПоле("NAME", 2, 25, 0);

ДБФ.СоздатьФайл("mydb.dbf");

ДобавитьИндекс(<Название>, <Выражение>, <Уникальность>, <Убывание>, <Фильтр>) – индекс в описание структуры базы.

Параметры:

<Название> – имя создаваемого индекса.

<Выражение> – индексное выражение.

<Уникальность> признак уникальности индекса. 1 – уникальный. 0 – не уникальный.

<Убывание> – флаг направления убывания индекса: 1 – индекс по убыванию значения ключа. 0 – по возрастанию значения ключа.

<Фильтр> – фильтр индекса.

Пример:

ДБФ = СоздатьОбъект("XBase");

ДБФ.ДобавитьПоле("CODE", 1, 19, 3);

ДБФ.ДобавитьПоле("NAME", 2, 25, 0);

ДБФ.ДобавитьИндекс("IDXCODE", "CODE", 1, 0, "");

ДБФ.ДобавитьИндекс("IDXNAME", "NAME", 0, 0, "");

ДБФ.СоздатьФайл("mydb.dbf", "mydb.cdx");

СоздатьИндексныйФайл(<ИмяФайла>) – создает индексный файл. Создаваемый индексный файл будет содержать все индексы, которые были созданы на текущий момент методом ДобавитьИндекс.

Параметры:

<ИмяФайла> – имя индексного файла.

Пример:

ДБФ.ДобавитьИндекс("IDXCODE", "CODE", 1, 0, "");

ДБФ.ДобавитьИндекс("IDXROOM", "ROOM+FIO", 0, 0, "");

ДБФ.СоздатьИндексныйФайл("idxcnew.cdx");

КодоваяСтраница(<Режим>) – позволяет установить режим кодировки для чтения и записи значений строковых полей в файл базы данных. После открытия, XBase–объект всегда находится в режиме DOS–кодировки.

Параметры:

<Режим> – необязательный параметр. 0 – Windows–кодировка; 1 – DOS–кодировка. Если параметр не задан, то режим кодировки не меняется (используется для определения текущего режима кодировки без его смены).

Возвращаемое значение: текущее числовое значение режима кодировки (на момент до исполнения метода).

Пример:

ДБФ.КодоваяСтраница(1);

КодОшибки() – возвращает код завершения последней выполненной операции.

Возвращаемое значение: код последней ошибки.

Пример:

КО = ДБФ.КодОшибки();

Возвращаемые коды ошибок:

Код ошибки Причина ошибки

–10 Ошибка закрытия файла

–20 Ошибка создания файла

–30 Ошибка определения длины файла

–40 Ошибка установки длины файла

–50 Ошибка при попытке заблокировать файл

–60 Ошибка при открытии файла

–70 Ошибка чтения файла

–80 Ошибка удаления файла

–90 Ошибка переименования файла

–100 Ошибка позиционирования в файле

–110 Ошибка снятия блокировки с файла

–120 Ошибка записи в файл

–200 Файл не является базой данных DBF–формата

–210 Неопознанное имя поля

–220 Неопознанный тип поля

–230 Запись слишком длинная

–300 Индексный файл не содержит информации о записи

–310 Нарушение структуры индексного файла

–330 Указанное имя индекса недоступно

–340 Ошибка уникальности индекса

–400 Ожидается запятая или скобка

–410 Выражение не завершено

–422 IIF() требует параметров одинаковой длины

–430 Неверное число параметров

–440 Слишком сложное выражение

–450 Пропущена правая скобка

–460 Неверный тип подвыражения

–470 Неопознанная функция

–480 Неопознанный оператор

–490 Неопознанное значение

–500 Выражение не завершено символом двойной кавычки

–920 Недостаточно памяти

12.2 Запись данных в DBF–файл

Рассмотрим пример выгрузки данных в DBF–файл. Пусть информацию из справочника сотрудники необходимо выгрузить в текстовый файл и создать индексы по ФИО и дате приема.

Создаваемый файл будет иметь следующую структуру (тип поля указан в терминах БД):

Имя поля	Тип	Длина	Точность
FIO	C	100
Dolg	C	30
Podrazd	C	100
Oklad	N	10	2
Priem	D
Uvoln	D
Tip	C	15

В Конфигураторе откройте справочник Сотрудники и кнопкой Формы списка откройте форму ФормаСписка. Поместите на форму кнопку Выгрузить в DBF (рисунок 12.2.1).

Рисунок 12.2.1

В окне свойств кнопки укажите в качестве формулы процедуру Выгрузка(). В программном модуле формы запрограммируйте указанную процедуру:

Процедура Выгрузка()

ДБФ = СоздатьОбъект("XBase");

// задаем структуру базы: имена, типы и размерность полей

ДБФ.ДобавитьПоле("FIO", "S", 100,0);

ДБФ.ДобавитьПоле("Dolg", "S", 30,0);

ДБФ.ДобавитьПоле("Podrazd", "S", 100,0);

ДБФ.ДобавитьПоле("Oklad", "N", 10, 2);

ДБФ.ДобавитьПоле("Priem", "D",0,0);

ДБФ.ДобавитьПоле("Uvoln", "D",0,0);

ДБФ.ДобавитьПоле("Tip", "S", 15,0);

// создаем индексы:

// по ФИО

ДБФ.ДобавитьИндекс("IDXFIO", "FIO", 0, 0, "");

// по дате приема

ДБФ.ДобавитьИндекс("IDXPRIEM", "PRIEM", 0, 0, "");

// создаем dbf–файл и индекс

ДБФ.СоздатьФайл("sotr.dbf", "sort.cdx");

// устанавливаем кодовую страницу Windows

ДБФ.КодоваяСтраница(0);

Сотр=СоздатьОбъект("Справочник.Сотрудники");

Сотр.ВыбратьЭлементы();

// проходим по элементам справочника Сотрудники

Пока Сотр.ПолучитьЭлемент()=1 Цикл

// если это не групп

Если Сотр.ЭтоГруппа()=0 Тогда

// добавляем данные в dbf–файл

ДБФ.Добавить();

ДБФ.FIO=Сотр.Наименование;

ДБФ.Dolg=Сотр.Должности.Наименование;

ДБФ.Podrazd=Сотр.Родитель;

ДБФ.Oklad=Сотр.Оклад;

ДБФ.Priem=Сотр.ДатаПриема;

ДБФ.Uvoln=Сотр.ДатаУвольнения;

ДБФ.Tip=Сотр.ТипРаботника;

// записываем

ДБФ.Записать();

КонецЕсли;

КонецЦикла;

// закрываем базу

ДБФ.ЗакрытьФайл();

КонецПроцедуры

Сохраните конфигурацию и запустите 1С в режиме Предприятие. Выполните выгрузку данных в DBF–файл и закройте 1С: Предприятие.

Проверьте, что на диске в каталоге, где расположена создаваемая конфигурация, появились файлы sotr.dbf, sort.cdx. Откройте файл sotr.dbf с помощью какой–либо СУБД, например, FoxPro илиVisual FoxPro, и просмотрите данные, подключите по очереди индексы.

12.3 Чтение данных из DBF–файла

Теперь рассмотрим чтение данных из DBF–файла. Допустим, имеется файл org.dbf, содержащий сведения об организациях–клиентах, со следующей структурой:

Имя поля	Тип	Длина	Точность	Комментарий
Name	C	100		Наименование организации
Adress	C	100		Юридический адрес
INN	C	12		ИНН
Shet	C	20		Расчетный счет

Необходимо создать справочник соответствующей структуры и загрузить туда данные из файла org.dbf.

Сначала создадим сам файл org.dbf. Для этого воспользуемся FoxPro или Visual FoxPro. Созданную базу сохраните в тот, каталог, где находится конфигурация. После создания структуры базы занесите туда 8–10 записей, и файл, который необходимо загрузить, готов.

Далее в режиме конфигуратора создаем справочник Клиенты (длина наименования –100) со следующими реквизитами:

• Адрес: Синоним и Комментарий – Юридический адрес, Тип – Строка, Длина – 100;

• ИНН: Синоним и Комментарий – ИНН, Тип – Строка, Длина – 12;

• Счет: Синоним и Комментарий – Расчетный счет, Тип – Строка, Длина – 20.

Включите в меню Справочники пункт Организации–клиенты. Создайте форму списка для данного справочника и разместите на форме кнопку Загрузить из DBF (рисунок 12.3.1), указав в качестве формулы процедуру Загрузка().

Рисунок 12.3.1

В программном модуле запрограммируем процедуру Загрузка():

Процедура Загрузка()

ДБФ = СоздатьОбъект("XBase");

// открываем файл

ДБФ.ОткрытьФайл("org.dbf");

// проверяем

Если ДБФ.Открыта() = 0 Тогда

Предупреждение("Не смогли открыть Базу!");

Возврат;

КонецЕсли;

// устанавливаем кодовую страницу Windows

ДБФ.КодоваяСтраница(0);

Клиент=СоздатьОбъект("Справочник.Клиенты");

// проходим в цикле с первой записи базы по последнюю

Для к=1 по ДБФ.КоличествоЗаписей() Цикл

// создаем новый элемент справочника

Клиент.Новый();

// записываем поля из базы

Клиент.Наименование=ДБФ.Name;

Клиент.Адрес=ДБФ.Adress;

Клиент.ИНН=ДБФ.INN;

Клиент.Счет=ДБФ.Shet;

// записываем элемент в справочник

Клиент.Записать();

// переходим на следующую запись базы

ДБФ.Следующая();

КонецЦикла;

// закрываем базу

ДБФ.ЗакрытьФайл();

КонецПроцедуры

Сохраните конфигурацию и загрузите 1С в режиме Предприятие. Откройте справочник Клиент и убедитесь, что он пуст. Затем нажмите кнопку Загрузить из DBF и убедитесь, что в справочнике появились элементы из базы org.dbf.

Задания:

В конфигурациях, созданных на прошлых занятиях, сделайте следующие изменения и дополнения:

Вариант 1

• выполните выгрузку данных из справочника Картины в DBF–файл;

• создайте справочник Коллекционеры (реквизиты – ФИО, Адрес, Контактный телефон) и загрузите в него данные из DBF–файл, предварительно созданного и заполненного в СУБД.

Вариант 2

• выполните выгрузку данных из справочника Товары в DBF–файл;

• создайте справочник Поставщики (реквизиты – Наименование организации, Адрес, Контактный телефон) и загрузите в него данные из DBF–файл, предварительно созданного и заполненного в СУБД.

Вариант 3

• выполните выгрузку данных из справочника Абоненты в DBF–файл;

• создайте справочник Мастера (реквизиты – ФИО, Квалификация, Контактный телефон) и загрузите в него данные из DBF–файл, предварительно созданного и заполненного в СУБД.

Вариант 4

• выполните выгрузку данных из справочника Каталог в DBF–файл;

• создайте справочник Читатели (реквизиты – ФИО, Адрес, Место работы/учебы) и загрузите в него данные из DBF–файл, предварительно созданного и заполненного в СУБД.

Вариант 5

• выполните выгрузку данных из справочника Налоги в DBF–файл;

• создайте справочник Организации (реквизиты – Наименование организации, Адрес, Контактный телефон) и загрузите в него данные из DBF–файл, предварительно созданного и заполненного в СУБД.

Вариант 6

• выполните выгрузку данных из справочника Соискатели в DBF–файл;

• создайте справочник Работодатели (реквизиты – Наименование организации, Адрес, Контактный телефон) и загрузите в него данные из DBF–файл, предварительно созданного и заполненного в СУБД.

Вариант 7

• выполните выгрузку данных из справочника Квартиры в DBF–файл;

• создайте справочник Покупатели (реквизиты – ФИО, Адрес, Контактный телефон) и загрузите в него данные из DBF–файл, предварительно созданного и заполненного в СУБД.

Вариант 8

• выполните выгрузку данных из справочника Номера в DBF–файл;

• создайте справочник Персонал (реквизиты – ФИО, Адрес, Контактный телефон) и загрузите в него данные из DBF–файл, предварительно созданного и заполненного в СУБД.

Вариант 9

• выполните выгрузку данных из справочника Подписка в DBF–файл;

• создайте справочник ПочтовыеОтделения (реквизиты – Название, Адрес, ФИО руководителя) и загрузите в него данные из DBF–файл, предварительно созданного и заполненного в СУБД.

Вариант 10

• выполните выгрузку данных из справочника Квартиры в DBF–файл;

• создайте справочник Мастера (реквизиты – ФИО, Адрес, Контактный телефон) и загрузите в него данные из DBF–файл, предварительно созданного и заполненного в СУБД.

Вариант 11

• выполните выгрузку данных из справочника Касса в DBF–файл;

• создайте справочник ЖелезнодорожныеСтанции (реквизиты – Город, Количество путей, Контактный телефон) и загрузите в него данные из DBF–файл, предварительно созданного и заполненного в СУБД.

Вариант 12

• выполните выгрузку данных из справочника Путевки в DBF–файл;

• создайте справочник Экскурсии (реквизиты – Название, Время выезда, Длительность) и загрузите в него данные из DBF–файл, предварительно созданного и заполненного в СУБД.

Вариант 13

• выполните выгрузку данных из справочника Обувь в DBF–файл;

• создайте справочник Поставщики (реквизиты – Название организации, Адрес, Контактный телефон) и загрузите в него данные из DBF–файл, предварительно созданного и заполненного в СУБД.

Вариант 14

• выполните выгрузку данных из справочника Драгоценности в DBF–файл;

• создайте справочник ДрагоценныеКамни (реквизиты – Название, Цена за карат, Цвет) и загрузите в него данные из DBF–файл, предварительно созданного и заполненного в СУБД.

Вариант 15

• выполните выгрузку данных из справочника Студенты в DBF–файл;

• создайте справочник Дисциплины (реквизиты – Название, Количество часов, Наличие экзамена) и загрузите в него данные из DBF–файл, предварительно созданного и заполненного в СУБД.

Контрольные вопросы:

1. Для чего используется тип данных XBase?

2. Что понимается под термином Поле?

3. Как обратиться к полю базы данных?

4. Какой тип полей не поддерживает тип XBase?

5. Как создать новую базу данных через объект XBase?

6. Как поменять кодовую таблицу?

7. Как узнать количество полей в структуре базы данных?

8. Как узнать количество записей в базе данных?